BBS in a Box 7/BBS in a Box - Macintosh - Volume VII (BBS in a Box) (January 1993).iso/Files/Hyper/C-Cl/Cardz.cpt/Hyper Cards/card_6314.txt

Text File | 1988-01-10 | 24KB | 919 lines

-- card: 6314 from stack: in
-- bmap block id: 2358
-- flags: 0000
-- background id: 5876
-- name: 1 Fold
----- HyperTalk script -----
on openCard
  hide bkgnd field "message"
  if the name of this card contains "Master" then
    show card field "message2"
  else
    hide card field "message2"
  end if
  if (the name of this card contains "1 Fold" or the name of this card contains "Master") then
    show bkgnd field "hideFold"
  else
    hide bkgnd field "hideFold"
  end if
end openCard


-- part 73 (field)
-- low flags: 00
-- high flags: 0000
-- rect: left=0 top=0 right=342 bottom=512
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 12
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: note


-- part 71 (field)
-- low flags: 80
-- high flags: 0001
-- rect: left=0 top=0 right=342 bottom=253
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: lefttext


-- part 4 (field)
-- low flags: 01
-- high flags: 0004
-- rect: left=3 top=23 right=202 bottom=142
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Control


-- part 50 (field)
-- low flags: 81
-- high flags: 2004
-- rect: left=279 top=163 right=298 bottom=482
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 1
-- font id: 3
-- text size: 14
-- style flags: 0
-- line height: 18
-- part name: message2


-- part 5 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=15 top=149 right=172 bottom=44
-- title width / last selected line: 0
-- icon id / first selected line: 21700 / 21700
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Home
----- HyperTalk script -----
on mouseUp
  global temp
  visual effect iris close to black
  dolist "Go...", "Cancel", temp,1
  get the result
  if it is not empty then
    if item 2 of it <> "Finder" then
      go to stack item 2 of it
    else
      finder
    end if
  end if
end mouseUp

on finder
  domenu finder
  get the result
  if it is not empty then domenu quit
  get the result
  if it is not empty then doment "quit hypercard"
end finder


-- part 20 (field)
-- low flags: 81
-- high flags: 0001
-- rect: left=203 top=24 right=65 bottom=408
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: hidetitle


-- part 27 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=51 top=149 right=172 bottom=79
-- title width / last selected line: 0
-- icon id / first selected line: 26635 / 26635
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Help
----- HyperTalk script -----
on mouseUp
  go to card 1
  click at loc of card button "Help"
end mouseUp




-- part 47 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=58 top=78 right=104 bottom=78
-- title width / last selected line: 65535
-- icon id / first selected line: -15797 / 49739
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Delete
----- HyperTalk script -----
on mouseUp
  set lockScreen to true
  set cursor to 4
  get the name of this card
  if it contains "Master" then answer "You can't delete the Master cards." with "OK"
  if it is "OK" then exit mouseup
  answer "Are you sure?" with "No Way!" or "Do it"
  if it is "No Way!" then exit mouseUp
  get first line of card field "control"
  put it into cardName
  repeat for the number of cards
    find cardName in field "Control"
    get the result
    if it is not empty then exit repeat
    if the name of this card contains "Master" then
      go next
    else
      domenu "delete card"
    end if
  end repeat
  go to first card
  set lockScreen to false
end mouseUp



-- part 48 (button)
-- low flags: 00
-- high flags: 0000
-- rect: left=17 top=75 right=107 bottom=42
-- title width / last selected line: 0
-- icon id / first selected line: 1002 / 1002
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: New
----- HyperTalk script -----
on mouseDown
  global cardType
  show bkgnd field "message"
  put the mouseloc into mousePlace
  put item 1 of mousePlace - 20 into horiz
  put item 2 of mousePlace - 10 into vert
  get PopUpMenu("1 Fold;2 Fold", 1, vert, horiz)
  set lockscreen to true
  set cursor to 4
  push card
  if it="0" then
    hide bkgnd field "message"
    exit mouseDown
    set lockscreen to false
  end if
  if it="1" then
    put "1 Fold" into cardType
    oneFold
  else
    put "2 Fold" into cardType
    twoFold
  end if
  hide bkgnd field "message"
end mouseDown

on oneFold
  global cardType
  go to second card
  domenu "Copy Card"
  ask "Name your Christmas Card..."
  if it is empty then
    pop card
    set lockscreen to false
    exit oneFold
  else
    put it into pictitle
  end if
  go to last card
  domenu "Paste Card" -- front panel
  put pictitle into first line of card field "Control"
  put "1 Fold" into second line of card field "Control"
  put "Front Panel" into last line of card field "Control"
  set name of this card to cardType
  domenu "Paste Card" -- inside-front panel
  put pictitle into first line of card field "Control"
  put "1 Fold" into second line of card field "Control"
  put "Inside-Front Panel" into last line of card field "Control"
  set name of this card to cardType
  domenu "Paste Card" -- inside-back panel
  put pictitle into first line of card field "Control"
  put "1 Fold" into second line of card field "Control"
  put "Inside-Back Panel" into last line of card field "Control"
  set name of this card to cardType
  domenu "Paste Card" -- back panel
  put pictitle into first line of card field "Control"
  put "1 Fold" into second line of card field "Control"
  put "Back Panel" into last line of card field "Control"
  set name of this card to cardType
  repeat for 3
    go prev
  end repeat
  put "" into cardType
  hide bkgnd field "message"
  set lockscreen to false
end oneFold

on twoFold
  global cardType
  go to second card
  domenu "Copy Card"
  ask "Name your Christmas Card..."
  if it is empty then
    pop card
    set lockscreen to false
    exit twoFold
  else
    put it into pictitle
  end if
  go to last card
  domenu "Paste Card" -- inside right-left panels
  put pictitle into first line of card field "Control"
  put "2 Fold" into second line of card field "Control"
  put "Inside-Right" into bkgnd field "panelleft"
  put "Inside-Left" into bkgnd field "panelright"
  put "Inside Right-Left" into last line of card field "Control"
  set name of this card to cardType
  hide bkgnd field hideFold
  domenu "Paste Card" -- back-front panels
  put pictitle into first line of card field "Control"
  put "2 Fold" into second line of card field "Control"
  put "Back" into bkgnd field "panelleft"
  put "Front" into bkgnd field "panelright"
  put "Back-Front Panels" into last line of card field "Control"
  set name of this card to cardType
  hide bkgnd field hideFold
  go prev
  put "" into cardType
  hide bkgnd field "message"
  set lockscreen to false
end twoFold



-- part 57 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=50 top=113 right=139 bottom=77
-- title width / last selected line: 0
-- icon id / first selected line: 1014 / 1014
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Prev
----- HyperTalk script -----
on mouseUp
  set lockscreen to true
  set cursor to 4
  go prev
  get first line of card field "control"
  put it into cardName
  repeat for the number of cards
    if the name of this card contains "Master" then exit mouseUp
    if first line of card field "control" contains cardName then
      if the name of this card contains "1 Fold" then
        oneFold
      else
        twoFold
      end if
    end if
  end repeat
end mouseUp

on oneFold
  put "false" into it
  repeat until it contains "true"
    if first word of last line of card field "control" <> "Front" then
      go prev
    else
      exit oneFold
    end if
  end repeat
  set lockscreen to false
end oneFold

on twoFold
  put "false" into it
  repeat until it contains "true"
    if last line of card field "control" <> "Inside Right-Left" then
      go prev
    else
      put "true" into it
    end if
  end repeat
  set lockscreen to false
end twoFold



-- part 58 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=108 top=113 right=139 bottom=135
-- title width / last selected line: 0
-- icon id / first selected line: 1013 / 1013
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Next
----- HyperTalk script -----
on mouseUp
  set cursor to 4
  set lockscreen to true
  get first line of card field "control"
  put it into cardName
  go next
  if the name of this card contains "Master" then exit mouseUp
  repeat until first line of card field "control" <> cardName
    go next
  end repeat
end mouseUp



-- part 69 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=12 top=111 right=145 bottom=47
-- title width / last selected line: 0
-- icon id / first selected line: 31975 / 31975
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Menus
----- HyperTalk script -----
on mouseUp
  if visible of bkgnd field toggle is false then
    show menuBar
    show bkgnd field toggle
  else
    hide menuBar
    hide bkgnd field toggle
  end if
end mouseUp



-- part 72 (field)
-- low flags: 80
-- high flags: 0001
-- rect: left=261 top=0 right=342 bottom=512
-- title width / last selected line: 0
-- icon id / first selected line: 0 / 0
-- text alignment: 0
-- font id: 3
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: righttext


-- part 81 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=79 top=113 right=139 bottom=106
-- title width / last selected line: 0
-- icon id / first selected line: 1015 / 1015
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Scroll
----- HyperTalk script -----
on mouseUp
  global list1,list2
  set lockScreen to true
  if the name of this card contains "Master" then
    play doo tempo 300 c c
    put "There are no other segments in the master card.  Going to next."
    set lockscreen to false
    visual effect venetian blinds
    go next
    hide msg
    exit mouseUp
  end if
  if the name of this card contains "1 Fold" then
    oneFold
  else
    twoFold
  end if
end mouseUp

on oneFold
  global list1
  doList "Go", "Cancel", list1,1
  get the result
  if it is not empty then
    set cursor to 4
    put item 2 of it into chosen
    get first line of card field "control"
    put it into cardName
    set lockscreen to true
    repeat for the number of cards
      if (first line of card field "Control" = cardName and last line of card field "Control" = chosen) then
        set lockscreen to false
        exit oneFold
      else
        go next
      end if
    end repeat
    play harpsichord h6
    put "Something's wrong.  I couldn't find that panel!"
    go to first card
    wait 2 seconds
    play harpsichord h5
    hide msg
  end if
  set lockscreen to false
end oneFold

on twoFold
  set lockscreen to false
  if card field "Control" contains "Right-Left" then
    visual effect scroll up
    go next
    if card field "Control" contains "Back-Front" then
      exit twoFold
    end if
  else
    visual effect scroll down
    go prev
    if card field "Control" contains "Right-Left" then exit twoFold
  end if
  play harpsichord h6
  put "Something's wrong.  I couldn't find that panel!"
  go to first card
  wait 2 seconds
  play harpsichord h5
  hide msg
end twoFold


-- part 82 (button)
-- low flags: 00
-- high flags: 2000
-- rect: left=94 top=145 right=177 bottom=119
-- title width / last selected line: 0
-- icon id / first selected line: 20486 / 20486
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Note
----- HyperTalk script -----
on mouseUp
  if the name of this card contains "Master" then
    play harpsichord tempo 300 h6 h5 h6
    answer "You can't enter notes on the Master card..." with "Okay"
    if it is "Okay" then exit mouseUp
  end if
  if (the visible of card field "note" is true or the visible of card field "lefttext" is true or the visible of card field "righttext" is true) then
    answer "Clear and hide note?" with "Yes" or "No"
    if it is "Yes" then
      put "" into card field "note"
      hide card field "note"
      put "" into card field "lefttext"
      hide card field "lefttext"
      put "" into card field "righttext"
      hide card field "righttext"
      exit mouseUp
    else
      exit mouseUp
    end if
  else
    if the name of this card contains "1 Fold" then
      oneFold
    else
      twoFold
    end if
  end if
end mouseUp

on oneFold
  show card field "note"
  play harpsichord c
  put "Please choose a font..."
  click at loc of card field "note"
  domenu "Text Style..."
  put ""
  hide msg
  answer "Do you want to show lines?" with "Yes" or "No"
  if it is "Yes" then
    set showLines of card field "note" to true
  else
    set showLines of card field "note" to false
  end if
end oneFold

on twoFold
  show card field "lefttext"
  show card field "righttext"
  play harpsichord C
  put "Please choose a font for the left panel..."
  tabKey
  click at loc of card field "lefttext"
  domenu "Text Style..."
  answer "Do you want to show lines?" with "Yes" or "No"
  if it is "Yes" then
    set showLines of card field "lefttext" to true
  else
    set showLines of card field "lefttext" to false
  end if
  tabKey
  play harpsichord G
  put "And now the right panel..."
  click at loc of card field "righttext"
  domenu "Text Style..."
  answer "Do you want to show lines?" with "Yes" or "No"
  if it is "Yes" then
    set showLines of card field "righttext" to true
  else
    set showLines of card field "righttext" to false
  end if
  put ""
  hide msg
end twoFold



-- part 83 (button)
-- low flags: 00
-- high flags: A000
-- rect: left=89 top=82 right=102 bottom=128
-- title width / last selected line: 0
-- icon id / first selected line: 17794 / 17794
-- text alignment: 1
-- font id: 0
-- text size: 12
-- style flags: 0
-- line height: 16
-- part name: Print
----- HyperTalk script -----
on mouseUp
  global cardCopies,printerType
  set loc of message to 10,170
  if the name of this card contains "Master" then
    play harpsichord tempo 300 h6 h5
    answer "You don't want to print the Master card!" with "OK"
    if it is "OK" then exit mouseUp
  end if
  push card
  play boing
  answer "Make your choice..." with "Forget It" or "Chooser" or "Print"
  if it is "Forget It" then exit mouseUp
  if It is "Chooser" then
    domenu "Chooser"
  end if
  answer "What printer?" with "LaserWriter" or "ImageWriter"
  put it into printerType
  ask "How many?" with "1"
  if it is empty then
    exit mouseUp
  else
    put it into cardCopies
  end if
  if the name of this card contains "1 Fold" then
    oneFold
  else
    twoFold
  end if
end mouseUp

on oneFold
  global cardCopies,printerType
  set the cursor to 4
  set lockscreen to true
  get first line of card field "control"
  put it into cardName
  play harpsichord c e g
  flash 1
  if printerType="LaserWriter" then
    put "Select ""e&"Manual Feed""e&" from the following dialog box."
    wait 3 seconds
  else
    put "This type of card works best with cut sheet paper..."
    wait 3 seconds
    answer "Load first sheet and Continue..." with "Cancel" or "Continue"
    if it is "Cancel" then
      hide msg
      exit oneFold
    else
      put "Select ""e&"Darker Printing""e&" for better quality."
      wait 3 seconds
    end if
  end if

  open printing with dialog

  repeat for the number of cards
    if (first line of card field "control" = cardName and last line of card field "control" = "Back Panel") then
      choose select tool
      domenu "select all"
      domenu "flip horizontal"
      domenu "flip vertical"
      choose browse tool
      exit repeat
    else
      go next
    end if
  end repeat

  repeat for cardCopies times
    repeat for the number of cards
      if (first line of card field "control" = cardName and last line of card field "control" = "Back Panel") then
        exit repeat
      else
        go next
      end if
    end repeat
    if the visible of bkgnd field toprule is false then enterKey
    if the visible of card field "control" is true then tabKey
    print card
    if the visible of bkgnd field toprule is true then enterKey
    if the visible of card field "control" is false then tabKey

    repeat for the number of cards
      if (first line of card field "control" = cardName and last line of card field "control" = "Front Panel") then
        exit repeat
      else
        go next
      end if
    end repeat
    if the visible of bkgnd field toprule is false then enterKey
    if the visible of card field "control" is true then tabKey
    print card
    if the visible of bkgnd field toprule is true then enterKey
    if the visible of card field "control" is false then tabKey
  end repeat

  close printing

  repeat for the number of cards
    if (first line of card field "control" = cardName and last line of card field "control" = "Back Panel") then
      choose select tool
      domenu "select all"
      domenu "flip horizontal"
      domenu "flip vertical"
      choose browse tool
      exit repeat
    else
      go next
    end if
  end repeat

  answer "Continue when first page is done..." with "Cancel" or "Continue"
  if it is "Cancel" then
    exit oneFold
  else
    play harpsichord tempo 300 h6 h5 h6
    flash 2
  end if

  if printerType = "ImageWriter" then
    put "Now reinsert the printout so that the FRONT PANEL faces you..."
    wait 3 seconds
    play harpsichord c
    flash 1
    put "...in an UPRIGHT position (BACK PANEL will be UPSIDE DOWN)."
    wait 2 seconds
    play harpsichord e
    flash 1
    answer "Continue when you are ready..." with "Cancel" or "Continue"
    if it is "Cancel" then
      hide msg
      exit oneFold
    else
      play harpsichord g
      flash 1
    end if
  else
    put "Now prepare to refeed the cards through the LaserWriter..."
    wait 3 seconds
    play harpsichord c
    flash 1
    put "...FACE DOWN, BACK PANEL through FIRST (wait for the yellow light)."
    wait 2 seconds
    play harpsichord e
    flash 1
    answer "Continue when you are ready..." with "Cancel" or "Continue"
    if it is "Cancel" then
      hide msg
      exit oneFold
    else
      play harpsichord g
      flash 1
    end if
  end if

  repeat for the number of cards
    if (first line of card field "control" = cardName and last line of card field "control" = "Front Panel") then
      exit repeat
    else
      go next
    end if
  end repeat

  open printing

  repeat for cardCopies times
    repeat for 2 times
      go next
      if the visible of bkgnd field toprule is false then enterKey
      if the visible of card field "control" is true then tabKey
      print card
      if the visible of bkgnd field toprule is true then enterKey
      if the visible of card field "control" is false then tabKey
    end repeat
    repeat for 2 times
      go prev
    end repeat
  end repeat

  close printing

  pop card
  put "All done, Boss."
  play harpsichord c5 g4 e c
  hide msg
  set lockscreen to false
end oneFold

on twoFold
  global cardCopies,printerType
  set cursor to 4
  set lockscreen to true
  play harpsichord c e g
  flash 1
  if printerType="LaserWriter" then
    open printing
  else
    put "Select ""e&"Darker Printing""e&" for better quality."
    wait 3 seconds
  end if

  if card field "Control" contains "Back-Front" then go prev
  if card field "Control" contains "Right-Left" then
    choose select tool
    domenu "select all"
    domenu "flip horizontal"
    domenu "flip vertical"
    choose browse tool

    open printing with dialog

    repeat for cardCopies times
      if the visible of bkgnd field toprule is false then enterKey
      if the visible of card field "control" is true then tabKey
      show bkgnd field "hidefold"
      hide bkgnd field "panelleft"
      hide bkgnd field "panelright"
      print card
      go next
      if the visible of bkgnd field toprule is false then enterKey
      if the visible of card field "control" is true then tabKey
      show bkgnd field "hidefold"
      hide bkgnd field "panelleft"
      hide bkgnd field "panelright"
      print card
      go prev
    end repeat

    close printing
    if the visible of bkgnd field toprule is true then enterKey
    if the visible of card field "control" is false then tabKey
    show bkgnd field "panelleft"
    show bkgnd field "panelright"
    go next
    if the visible of bkgnd field toprule is true then enterKey
    if the visible of card field "control" is false then tabKey
    show bkgnd field "panelleft"
    show bkgnd field "panelright"
    go prev
    choose select tool
    domenu "select all"
    domenu "flip horizontal"
    domenu "flip vertical"
    choose browse tool

  else
    play harpsichord h6
    put "Something's wrong.  I couldn't find that panel!"
    go to first card
    wait 2 seconds
    play harpsichord h5
    hide msg
    exit twoFold
  end if
  hide msg
  set lockscreen to false
end twoFold


-- part contents for card part 4
----- text -----
1 Fold Card Example
1 Fold








Inside-Back Panel


-- part contents for background part 10
----- text -----
Commercial sale of this stack is prohibited without the author's permission.

-- part contents for background part 5
----- text -----
1 Fold, 2 Fold

-- part contents for background part 19
----- text -----
You must hold down the mouse button to see the list.

-- part contents for card part 50
----- text -----
You shouldn't draw on this card because whatever you draw will be copied onto your new cards.  Use the "New Card" icon, then draw on the new card.

-- part contents for card part 73
----- text -----


                                     Here's an example of how you can add text to
                                     your cards.  This text is in a transparent
                                    field that you can toggle on or off with the
                                    icon in the control panel (see Help).  Using this
                                    method to enter text instead of using the
                                    I-beam from the paint palette insures that
                                    you'll get high-quality fonts when you print your
                                    cards on a LaserWriter.  It also makes it
                                    a lot easier to edit your cards later on.
                                    But note also that text in fields cannot be
                                    flipped upside        down, so this may
                         cause problems when         used in some card
                            segments — like                  the back of this
                                                                                           one.